มินิโปรเจค Arduino เปิดปิดไฟ 220V และ หรี่ไฟบ้านด้วยเสียง

5 ปีที่ผ่านมา
โดย เจ้าของร้าน

ควบคุมการติด-ดับ และ หรี่แสงสว่างหลอดไฟด้วยเสียงปรบมือ

แนะนำ : ชุดประกอบสำเร็จ Arduino ควบคุมการติด-ดับ และ หรี่แสงสว่างหลอดไฟด้วยเสียงปรบมือ

  

การทำ มินิโปรเจค Arduino เปิดปิดไฟ 220V และ หรี่ไฟบ้านด้วยเสียง




เป้าหมายและหลักการทำงานของโปรเจค

ต้องการควบคุม เปิดปิดไฟด้วยเสียง รวมทั้งหรี่ไฟด้วยเสียง เพื่อเป็นการประหยัดพลังงาน และความสะดวกในการควบคุม ซึ่งจะทำให้หลอดไฟกินไฟน้อยลง นอกจากนั้นยังช่วยทำให้ยืดอายุหลอดไฟได้ยาวนานขึ้น เพราะไม่ต้องทำงานเต็มกำลังความสว่าง 100% ตลอดเวลา โดยสามารถเลือกความสว่างและเลิกใช้งานได้ตามความเหมาะสม ด้วยเสียง ดังนี้


1. เสียงปรบมือ 1 ครั้ง ให้หลอดไฟติด 100 % แต่ถ้าหลอดไฟติดอยู่ให้ดับ
2. เสียงปรบมือ 2 ครั้ง ให้หรี่ไฟหรือความสว่างลดลงเหลือ 60 %
3. เสียงปรบมือ 3 ครั้ง ให้หรี่ไฟหรือความสว่างลดลงลงเหลือ 30 %


อุปกรณ์ที่ใช้ในโปรเจค

2. Sensor Shield V 5.0

3.  Voice Sound Detection Sensor Module

4. Jumper (F2F) 20cm Female to Female

5. 1 Channel AC Light Lamp Dimmer Module

6. AC Power Cord 2 Pin Plug

7. หลอดไส้ร้อน และ ขั้วหลอดไฟ

8. Adapter DC 9V 1A Power Supply




อุปกรณ์ไฟฟ้าอื่นๆ เช่น หลอดไฟ , ปลั๊กไฟ , ขั้วหลอดไฟ , สายไฟ หาซื้อได้ตามร้านขายอุปกรณ์ไฟฟ้าทั่วๆไป

*** การใช้งานแบบไม่ต้องการเชื่อมต่อสาย USB กับ คอมพิวเตอร์ ให้ใช้ Adapter DC 9V 1A Power Supply เป็นแหล่งจ่ายไฟ เสียบเข้ากับ DC Power Jack ของ  บอร์ด Arduino ***


(เพื่อความปลอดภัย : ผู้ทำโปรเจค ควรมี ความรู้ด้านไฟฟ้าเป็นอย่างดี)

 

ขั้นตอนการทำโปรเจค


1.  ทดสอบการทำงาน Dimmer Module

ประกอบ Sensor Shield เข้ากับ Arduino UNO





ประกอบ Sensor Shield V 5.0


เชื่อมต่อ Sensor Shield กับ Dimmer Module
 



เชื่อมต่อ Dimmer Module กับ  อุปกรณ์ไฟฟ้าอื่นๆ


( หลอดไฟควรมีคุณสมบัติหรีไฟได้ เช่น หลอดไส้ร้อนแบบธรรมดา 40 - 100 วัตต์ )



ติดตั้งไลบรารี RBDdimmer โดยดาวน์โหลดไลบรารี RBDdimmer ตามลิงค์ด้านล่าง


https://github.com/RobotDynOfficial/RBDDimmer


ไปที่ Clone or download -> Download ZIP



เปิดโปรแกรม Arduino IDE

ไปที่ Skecth -> Include Library -> Add .ZIP Library...



ไปที่ ไลบรารี RBDDimmer-master.zip ที่เรา ดาวน์โหลด มา -> Open

ตรวจสอบที่ Skecth -> Include Library  จะพบ ไลบรารี RBDdimmer  เพิ่มเข้ามาใน Arduino IDE ของเรา

 
เชื่อมต่อสาย USB ระหว่าง คอมพิวเตอร์ กับ บอร์ด Arduino


 
 
เปิดโปรแกรม Arduino IDE เขียนโค้ดดังนี้



#include <RBDdimmer.h>

dimmerLamp dimmer4(4); //initialase port for dimmer: name(PinNumber);


void setup() {

Serial.begin(9600);

dimmer4.begin(NORMAL_MODE, ON); //dimmer initialisation: name.begin(MODE, STATE)

Serial.println("--- Simple dimmer example ---");

dimmer4.setState(ON); // setState(ON/OFF);

}

void loop() {

// put your main code here, to run repeatedly:

dimmer4.setPower(90); // setPower(0-100%);

delay(5000);

dimmer4.setPower(60); // setPower(0-100%);

delay(5000);

}


ไปที่ Tools > Board เลือกเป็น Arduino/Genuino UNO
 




ไปที่ Tools > Port แล้วเลือกพอร์ตที่ปรากฏ (กรณีใช้เครื่องคอมพิวเตอร์ที่มี COM Port มากกว่าหนึ่ง  ให้เลือกตัวอื่นที่ไม่ใช่ COM1)

ในตัวอย่างเลือกเป็น "COM8"

(ถ้ายังว่าง หรือ เป็น COM1 ให้ตรวจสอบการติดตั้งไดร์เวอร์ การต่อสาย USB ของ Arduino UNO)
 



(ถ้าไม่พบให้ทำการติดตั้งไดร์เวอร์ก่อน) 

การติดตั้งโปรแกรม Arduino (IDE) และ การติดตั้งไดร์เวอร์
 

กดปุ่ม  เพื่ออัพโหลด

หากสามารถอัพโหลดโปรแกรมลงบอร์ดได้สำเร็จ จะแสดงคำว่า Done uploading. ที่แถบด้านล่าง




เสียบปลั๊กไฟ 220V AC หลอดไฟจะสว่าง 90%


และ 30% สลับไปมา




แสดงว่า การเชื่อมต่อ Dimmer Module ของเรานั้นถูกต้อง และ พร้อมใช้งานแล้ว



2.  ทดสอบเซ็นเซอร์เสียง Sound Detection Sensor
เชื่อมต่อ Sensor Shield กับ Sound Detection Sensor


 
เปิดโปรแกรม Arduino IDE อัพโหลดโค้ดดังนี้


int sound_sensor = 5;

int clap = 0;
long detection_range_start = 0;
long detection_range = 0;


void setup() {

Serial.begin(9600);
pinMode(sound_sensor, INPUT);
}

void loop() {
int status_sensor = digitalRead(sound_sensor);
if (status_sensor == 0) {
if (clap == 0) {
detection_range_start = detection_range = millis();
clap++;
} else if (clap > 0 && millis() - detection_range >= 40) {
detection_range = millis();
clap++;
}
}
if (millis() - detection_range_start >= 600) {

if (clap == 1) {

Serial.println("clap = 1");

}


else if (clap == 2) {

Serial.println("clap = 2");

}

else if (clap == 3) {

Serial.println("clap = 3");

}


clap = 0;
}
}

ทดสอบการทำงาน

ให้เอาไขควงหมุน ปรับค่าการรับสัญญาณเสียง โดยให้หมุนตัว R ปรับค่าได้ แบบ trimpot สีฟ้า


ให้ไฟ LED สีเขียว ด้านซ้ายมือติดดวงเดียว



เมื่อปรบมือให้  LED สีเขียวด้านขวามือ กระพริบ ตาม การปรบมือของเรา



เปิดหน้าต่าง Serial Monitor  โดยไปที่ Tools > Serial Monitor

มุมขวาล่าง ของ Serial Monitor เลือกเป็น 9600 baud  คือ ตั้งค่าความเร็วในการรับ-ส่งข้อมูล  คือ 9600 ตามที่เราเขียนโค้ดไว้

ทดสอบให้ได้ผลลัพธ์ดังนี้

1. เสียงปรบมือ 1 ครั้ง ให้  Serial Monitor แสดง clap = 1
2. เสียงปรบมือ 2 ครั้ง ให้  Serial Monitor แสดง clap = 2
3. เสียงปรบมือ 3 ครั้ง ให้  Serial Monitor แสดง clap = 3

 
ถ้ายังไม่ได้ให้ ปรับค่าการรับสัญญาณเสียง โดยให้หมุนตัว R ปรับค่าได้ แบบ trimpot สีฟ้า


3.  ทดสอบ โปรเจค เปิดปิดไฟ 220V และ หรี่ไฟบ้านด้วยเสียง


 เปิดโปรแกรม Arduino IDE อัพโหลดโค้ดดังนี้

 

#include <RBDdimmer.h>

dimmerLamp dimmer4(4);

int sound_sensor = 5;

int clap = 0;
long detection_range_start = 0;
long detection_range = 0;
boolean status_lights = false;


void setup() {
Serial.begin(9600);
pinMode(sound_sensor, INPUT);
dimmer4.begin(NORMAL_MODE, ON);
dimmer4.setState(OFF);
}

void loop() {
int status_sensor = digitalRead(sound_sensor);
if (status_sensor == 0)
{
if (clap == 0)
{
detection_range_start = detection_range = millis();
clap++;
}
else if (clap > 0 && millis() - detection_range >= 40)
{
detection_range = millis();
clap++;
}
}
if (millis() - detection_range_start >= 600)
{

if (!status_lights && clap == 1)
{

Serial.println("clap = 1 , Lamp = ON");
dimmer4.setState(ON);
dimmer4.setPower(100);
status_lights = true;
}

else if (status_lights && clap == 1)
{

Serial.println("clap = 1 , Lamp = OFF");
dimmer4.setState(OFF);
status_lights = false;
}

else if (status_lights && clap == 2)
{
Serial.println("clap = 2 , Lamp = 60%");
dimmer4.setPower(60);
}

else if (status_lights && clap == 3)
{
Serial.println("clap = 3 , Lamp = 30%");
dimmer4.setPower(30);
}
clap = 0;

}

}


จะได้ผลลัพธ์ตามคลิป




อธิบายโค้ด


#include <RBDdimmer.h>  // นำเข้าไลบรารี RBDdimmer เพื่อควบคุมหลอดไฟที่สามารถหรี่แสงได้
dimmerLamp dimmer4(4);  // สร้างออบเจ็กต์ dimmer4 เชื่อมต่อกับ pin 4 เพื่อควบคุมการหรี่ไฟของหลอดไฟ
int sound_sensor = 5;  // กำหนดตัวแปร sound_sensor เพื่อเชื่อมต่อกับ pin 5 ซึ่งใช้ในการอ่านข้อมูลจากเซนเซอร์เสียง
int clap = 0;  // ตัวแปร clap ใช้สำหรับนับจำนวนครั้งของการปรบมือ
long detection_range_start = 0;  // เก็บเวลาที่เริ่มตรวจจับเสียงในช่วงเวลาแรกของการปรบมือ
long detection_range = 0;  // เก็บเวลาที่ตรวจจับเสียงปรบมือล่าสุด
boolean status_lights = false;  // ตัวแปรสถานะของไฟ เก็บค่าว่าไฟเปิดอยู่หรือไม่ (true = เปิด, false = ปิด)
 
void setup() {  // ฟังก์ชัน setup() ทำงานเพียงครั้งเดียวตอนเริ่มต้น
Serial.begin(9600);  // เริ่มต้นการสื่อสารแบบอนุกรมที่อัตราการส่งข้อมูล 9600 bps
pinMode(sound_sensor, INPUT);  // กำหนด pin ของ sound_sensor เป็น INPUT เพื่ออ่านค่าจากเซนเซอร์เสียง
dimmer4.begin(NORMAL_MODE, ON);  // เริ่มต้นการทำงานของ dimmer4 ในโหมดปกติ (NORMAL_MODE) และตั้งให้สถานะเริ่มต้นเป็น ON
dimmer4.setState(OFF);  // ตั้งสถานะของไฟเป็นปิด (OFF) ตั้งแต่เริ่มต้น
}
  
void loop() {  // ฟังก์ชัน loop() จะทำงานวนซ้ำไปเรื่อยๆ เพื่อตรวจสอบและตอบสนองต่อเงื่อนไขต่างๆ
int status_sensor = digitalRead(sound_sensor);  // อ่านค่าจากเซนเซอร์เสียง ถ้าสัญญาณเป็น 0 หมายถึงมีการตรวจจับเสียงปรบมือ
if (status_sensor == 0)  // ตรวจสอบว่ามีการตรวจจับเสียงหรือไม่ (0 หมายถึงมีเสียง)
{
if (clap == 0)  // ถ้าค่าของ clap เป็น 0 หมายถึงนี่เป็นการปรบมือครั้งแรก
{
detection_range_start = detection_range = millis();  // เก็บเวลาที่เริ่มตรวจจับเสียงครั้งแรก (ในรูปแบบหน่วยเวลา millis() ซึ่งนับเป็นมิลลิวินาที)
clap++;  // เพิ่มค่า clap เป็น 1 เพื่อบ่งบอกว่ามีการปรบมือครั้งแรกเกิดขึ้นแล้ว
}
else if (clap > 0 && millis() - detection_range >= 40)  // ถ้ามีการปรบมือครั้งแรกแล้ว (clap > 0) และเวลาผ่านไปอย่างน้อย 40 มิลลิวินาทีตั้งแต่ปรบมือครั้งล่าสุด
{
detection_range = millis();  // อัปเดตเวลาที่ตรวจจับเสียงปรบมือครั้งล่าสุด
clap++;  // เพิ่มค่า clap เพื่อบันทึกจำนวนครั้งของการปรบมือ
}
}
if (millis() - detection_range_start >= 600)  // ถ้าเวลาผ่านไปอย่างน้อย 600 มิลลิวินาทีตั้งแต่เริ่มตรวจจับเสียงปรบมือครั้งแรก ให้เริ่มดำเนินการ
{
if (!status_lights && clap == 1)  // ถ้าไฟยังไม่เปิด (status_lights = false) และมีการปรบมือ 1 ครั้ง
{
Serial.println("clap = 1 , Lamp = ON");  // แสดงข้อความใน Serial Monitor ว่าปรบมือครั้งเดียวและเปิดไฟ
dimmer4.setState(ON);  // เปิดไฟ
dimmer4.setPower(100);  // ตั้งค่าความสว่างของไฟเป็น 100% (ไฟสว่างเต็มที่)
status_lights = true;  // อัปเดตสถานะไฟเป็นเปิด (true)
}
else if (status_lights && clap == 1)  // ถ้าไฟเปิดอยู่ (status_lights = true) และมีการปรบมือ 1 ครั้ง
{
Serial.println("clap = 1 , Lamp = OFF");  // แสดงข้อความใน Serial Monitor ว่าปรบมือครั้งเดียวและปิดไฟ
dimmer4.setState(OFF);  // ปิดไฟ
status_lights = false;  // อัปเดตสถานะไฟเป็นปิด (false)
}
else if (status_lights && clap == 2)  // ถ้าไฟเปิดอยู่และมีการปรบมือ 2 ครั้ง
{
Serial.println("clap = 2 , Lamp = 60%");  // แสดงข้อความใน Serial Monitor ว่าปรบมือ 2 ครั้งและตั้งความสว่างของไฟเป็น 60%
dimmer4.setPower(60);  // ตั้งค่าความสว่างของไฟเป็น 60%
}
else if (status_lights && clap == 3)  // ถ้าไฟเปิดอยู่และมีการปรบมือ 3 ครั้ง
{
Serial.println("clap = 3 , Lamp = 30%");  // แสดงข้อความใน Serial Monitor ว่าปรบมือ 3 ครั้งและตั้งความสว่างของไฟเป็น 30%
dimmer4.setPower(30);  // ตั้งค่าความสว่างของไฟเป็น 30%
}
clap = 0;  // รีเซ็ตตัวแปร clap เป็น 0 เพื่อเริ่มการตรวจจับใหม่ในการปรบมือครั้งต่อไป
}
}

ตะกร้า
( 0 )
▲
▼
รายการสั่งซื้อของฉัน
เข้าสู่ระบบด้วย
เข้าสู่ระบบ
สมัครสมาชิก

ยังไม่มีบัญชีเทพ สร้างบัญชีใหม่ ไม่มีค่าใช้จ่าย
สมัครสมาชิก (ฟรี)
รายการสั่งซื้อของฉัน
ข้อมูลร้านค้านี้
ร้านโรบอทสยาม อุปกรณ์หุ่นยนต์ Arduino
โรบอทสยาม อุปกรณ์หุ่นยนต์ Arduino
จําหน่าย อุปกรณ์หุ่นยนต์ Arduino , ESP8266, ESP32 , STM32 , micro:bit , Paspberry Pi รับประกอบหุ่นยนต์ ชุดคิทหุ่นยนต์ ตัวอย่างโปรเจค IoT (Internet of Things) อินเทอร์เน็ตของสรรพสิ่ง
เบอร์โทร : 095-226-2116
อีเมล : robotsiam16@gmail.com
ส่งข้อความติดต่อร้าน
เกี่ยวกับร้านค้านี้
ค้นหาสินค้าในร้านนี้
หรือค้นหาอย่างละเอียด
ค้นหาสินค้า
สินค้าที่ดูล่าสุด

{{pdata.name}}
ดูสินค้าทั้งหมดในร้าน
สินค้าที่ดูล่าสุด
บันทึกเป็นร้านโปรด
Join เป็นสมาชิกร้าน
แชร์หน้านี้
แชร์หน้านี้
↑
TOP เลื่อนขึ้นบนสุด
พูดคุย-สอบถาม